cb09b408c5455e8018f7c692f7a4ceedd47ff785
[zsh.git] / .zsh / zsh-syntax-highlighting / highlighters / brackets / brackets-highlighter.zsh
1 # -------------------------------------------------------------------------------------------------
2 # Copyright (c) 2010-2016 zsh-syntax-highlighting contributors
3 # All rights reserved.
4 #
5 # Redistribution and use in source and binary forms, with or without modification, are permitted
6 # provided that the following conditions are met:
7 #
8 # * Redistributions of source code must retain the above copyright notice, this list of conditions
9 # and the following disclaimer.
10 # * Redistributions in binary form must reproduce the above copyright notice, this list of
11 # conditions and the following disclaimer in the documentation and/or other materials provided
12 # with the distribution.
13 # * Neither the name of the zsh-syntax-highlighting contributors nor the names of its contributors
14 # may be used to endorse or promote products derived from this software without specific prior
15 # written permission.
16 #
17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
18 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
19 # FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
20 # CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
22 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
23 # IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
24 # OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
25 # -------------------------------------------------------------------------------------------------
26 # -*- mode: zsh; sh-indentation: 2; indent-tabs-mode: nil; sh-basic-offset: 2; -*-
27 # vim: ft=zsh sw=2 ts=2 et
28 # -------------------------------------------------------------------------------------------------
29
30
31 # Define default styles.
32 : ${ZSH_HIGHLIGHT_STYLES[bracket-error]:=fg=red,bold}
33 : ${ZSH_HIGHLIGHT_STYLES[bracket-level-1]:=fg=blue,bold}
34 : ${ZSH_HIGHLIGHT_STYLES[bracket-level-2]:=fg=green,bold}
35 : ${ZSH_HIGHLIGHT_STYLES[bracket-level-3]:=fg=magenta,bold}
36 : ${ZSH_HIGHLIGHT_STYLES[bracket-level-4]:=fg=yellow,bold}
37 : ${ZSH_HIGHLIGHT_STYLES[bracket-level-5]:=fg=cyan,bold}
38 : ${ZSH_HIGHLIGHT_STYLES[cursor-matchingbracket]:=standout}
39
40 # Whether the brackets highlighter should be called or not.
41 _zsh_highlight_highlighter_brackets_predicate()
42 {
43 [[ $WIDGET == zle-line-finish ]] || _zsh_highlight_cursor_moved || _zsh_highlight_buffer_modified
44 }
45
46 # Brackets highlighting function.
47 _zsh_highlight_highlighter_brackets_paint()
48 {
49 local char style
50 local -i bracket_color_size=${#ZSH_HIGHLIGHT_STYLES[(I)bracket-level-*]} buflen=${#BUFFER} level=0 matchingpos pos
51 local -A levelpos lastoflevel matching
52
53 # Find all brackets and remember which one is matching
54 for (( pos = 1; pos <= buflen; pos++ )) ; do
55 char=$BUFFER[pos]
56 case $char in
57 ["([{"])
58 levelpos[$pos]=$((++level))
59 lastoflevel[$level]=$pos
60 ;;
61 [")]}"])
62 if (( level > 0 )); then
63 matchingpos=$lastoflevel[$level]
64 levelpos[$pos]=$((level--))
65 if _zsh_highlight_brackets_match $matchingpos $pos; then
66 matching[$matchingpos]=$pos
67 matching[$pos]=$matchingpos
68 fi
69 else
70 levelpos[$pos]=-1
71 fi
72 ;;
73 ['"'\'])
74 # Skip everything inside quotes
75 pos=$BUFFER[(ib:pos+1:)$char]
76 ;;
77 esac
78 done
79
80 # Now highlight all found brackets
81 for pos in ${(k)levelpos}; do
82 if (( $+matching[$pos] )); then
83 if (( bracket_color_size )); then
84 _zsh_highlight_add_highlight $((pos - 1)) $pos bracket-level-$(( (levelpos[$pos] - 1) % bracket_color_size + 1 ))
85 fi
86 else
87 _zsh_highlight_add_highlight $((pos - 1)) $pos bracket-error
88 fi
89 done
90
91 # If cursor is on a bracket, then highlight corresponding bracket, if any.
92 if [[ $WIDGET != zle-line-finish ]]; then
93 pos=$((CURSOR + 1))
94 if (( $+levelpos[$pos] )) && (( $+matching[$pos] )); then
95 local -i otherpos=$matching[$pos]
96 _zsh_highlight_add_highlight $((otherpos - 1)) $otherpos cursor-matchingbracket
97 fi
98 fi
99 }
100
101 # Helper function to differentiate type
102 _zsh_highlight_brackets_match()
103 {
104 case $BUFFER[$1] in
105 \() [[ $BUFFER[$2] == \) ]];;
106 \[) [[ $BUFFER[$2] == \] ]];;
107 \{) [[ $BUFFER[$2] == \} ]];;
108 *) false;;
109 esac
110 }