Mode change
[zsh.git] / .zsh / plugins / per-directory-history.plugin.zsh
1 #!/usr/bin/env zsh
2 #
3 # This is a implementation of per directory history for zsh, some
4 # implementations of which exist in bash[1,2]. It also implements
5 # a per-directory-history-toggle-history function to change from using the
6 # directory history to using the global history. In both cases the history is
7 # always saved to both the global history and the directory history, so the
8 # toggle state will not effect the saved histories. Being able to switch
9 # between global and directory histories on the fly is a novel feature as far
10 # as I am aware.
11 #
12 #-------------------------------------------------------------------------------
13 # Configuration
14 #-------------------------------------------------------------------------------
15 #
16 # HISTORY_BASE a global variable that defines the base directory in which the
17 # directory histories are stored
18 #
19 #-------------------------------------------------------------------------------
20 # History
21 #-------------------------------------------------------------------------------
22 #
23 # The idea/inspiration for a per directory history is from Stewart MacArthur[1]
24 # and Dieter[2], the implementation idea is from Bart Schaefer on the the zsh
25 # mailing list[3]. The implementation is by Jim Hester in September 2012.
26 #
27 # [1]: http://www.compbiome.com/2010/07/bash-per-directory-bash-history.html
28 # [2]: http://dieter.plaetinck.be/per_directory_bash
29 # [3]: http://www.zsh.org/mla/users/1997/msg00226.html
30 #
31 ################################################################################
32 #
33 # Copyright (c) 2012 Jim Hester
34 #
35 # This software is provided 'as-is', without any express or implied warranty.
36 # In no event will the authors be held liable for any damages arising from the
37 # use of this software.
38 #
39 # Permission is granted to anyone to use this software for any purpose,
40 # including commercial applications, and to alter it and redistribute it
41 # freely, subject to the following restrictions:
42 #
43 # 1. The origin of this software must not be misrepresented; you must not claim
44 # that you wrote the original software. If you use this software in a product,
45 # an acknowledgment in the product documentation would be appreciated but is
46 # not required.
47 #
48 # 2. Altered source versions must be plainly marked as such, and must not be
49 # misrepresented as being the original software.
50 #
51 # 3. This notice may not be removed or altered from any source distribution..
52 #
53 ################################################################################
54
55 #-------------------------------------------------------------------------------
56 # configuration, the base under which the directory histories are stored
57 #-------------------------------------------------------------------------------
58 if ! [[ $ZSH_VERSION == 4.3.<4->* || $ZSH_VERSION == 4.<4->* \
59 || $ZSH_VERSION == <5->* ]]; then
60 return
61 fi
62
63 [[ -z $HISTORY_BASE ]] && HISTORY_BASE="$HOME/.directory_history"
64
65 #-------------------------------------------------------------------------------
66 # toggle global/directory history used for searching - ctrl-G by default
67 #-------------------------------------------------------------------------------
68
69 function per-directory-history-toggle-history() {
70 if [[ $_per_directory_history_is_global == true ]]; then
71 _per-directory-history-set-directory-history
72 print "\nusing local history\n"
73 else
74 _per-directory-history-set-global-history
75 print "\nusing global history\n"
76 fi
77 zle .push-line
78 zle .accept-line
79 }
80
81 autoload per-directory-history-toggle-history
82 zle -N per-directory-history-toggle-history
83 bindkey '^G' per-directory-history-toggle-history
84
85 #-------------------------------------------------------------------------------
86 # implementation details
87 #-------------------------------------------------------------------------------
88
89 _per_directory_history_directory="$HISTORY_BASE${PWD:A}/history"
90
91 function _per-directory-history-change-directory() {
92 _per_directory_history_directory="$HISTORY_BASE${PWD:A}/history"
93 mkdir -p ${_per_directory_history_directory:h}
94 if [[ $_per_directory_history_is_global == false ]]; then
95 #save to the global history
96 fc -AI $HISTFILE
97 #save history to previous file
98 local prev="$HISTORY_BASE${OLDPWD:A}/history"
99 mkdir -p ${prev:h}
100 fc -AI $prev
101
102 #discard previous directory's history
103 local original_histsize=$HISTSIZE
104 HISTSIZE=0
105 HISTSIZE=$original_histsize
106
107 #read history in new file
108 if [[ -e $_per_directory_history_directory ]]; then
109 fc -R $_per_directory_history_directory
110 fi
111 fi
112 }
113
114 function _per-directory-history-addhistory() {
115 print -sr -- ${1%%$'\n'}
116 fc -p $_per_directory_history_directory
117 }
118
119
120 function _per-directory-history-set-directory-history() {
121 if [[ $_per_directory_history_is_global == true ]]; then
122 fc -AI $HISTFILE
123 local original_histsize=$HISTSIZE
124 HISTSIZE=0
125 HISTSIZE=$original_histsize
126 if [[ -e "$_per_directory_history_directory" ]]; then
127 fc -R "$_per_directory_history_directory"
128 fi
129 fi
130 _per_directory_history_is_global=false
131 }
132 function _per-directory-history-set-global-history() {
133 if [[ $_per_directory_history_is_global == false ]]; then
134 fc -AI $_per_directory_history_directory
135 local original_histsize=$HISTSIZE
136 HISTSIZE=0
137 HISTSIZE=$original_histsize
138 if [[ -e "$HISTFILE" ]]; then
139 fc -R "$HISTFILE"
140 fi
141 fi
142 _per_directory_history_is_global=true
143 }
144
145
146 #add functions to the exec list for chpwd and zshaddhistory
147 chpwd_functions=(${chpwd_functions[@]} "_per-directory-history-change-directory")
148 zshaddhistory_functions=(${zshaddhistory_functions[@]} "_per-directory-history-addhistory")
149
150 #start in directory mode
151 mkdir -p ${_per_directory_history_directory:h}
152 _per_directory_history_is_global=false
153 _per-directory-history-set-global-history