missing colon
[zsh.git] / .zsh / functions / prompt_ganneff_setup
1 # -*- mode:sh -*-
2
3 # This prompt is based on work of other people.
4 #
5 # The prompt itself is based on various others:
6 # - The "design" is taken from Phil!'s ZSH prompt, as found on
7 # http://aperiodic.net/phil/prompt/
8 #
9 # - The tech using zstyle is inspired by the prompt as used by
10 # the grml-live system <http://grml.org>, see
11 # http://git.grml.org/?p=grml-etc-core.git;a=summary for details
12 # on theirs.
13 # A good number of their support functions are also taken, though
14 # they got renamed from grml_* to ganneff_* to have a single namespace
15 # here.
16 #
17 # - The winch function as seen in the prompt theme "bart", delivered
18 # with zsh
19
20 prompt_ganneff_help () {
21 cat <<__EOF0__
22 prompt ganneff
23
24 This is the prompt as used by (who would have guessed) Ganneff. By
25 default it is a two-line prompt. You can find its latest version at
26 http://git.ganneff.de/cgi-bin/gitweb.cgi?p=zsh.git;a=summary
27
28 The prompt itself is based on various others:
29 - The "design" is taken from Phil!'s ZSH prompt, as found on
30 http://aperiodic.net/phil/prompt/
31
32 - The technic using zstyle is inspired by the prompt as used by
33 the grml-live system <http://grml.org>, see
34 http://git.grml.org/?p=grml-etc-core.git;a=summary for details
35 on theirs.
36
37 The prompt integrates with zsh's prompt themes system and uses the
38 zstyle system for its configuration. It is configurable as much as
39 seems to make sense. In particular, these aspects are customisable:
40
41 - The items used in the prompt and their order (e.g. you can
42 remove \`user' from the list of activated items, which will
43 cause the user name to be omitted from the prompt string).
44
45 - The attributes used with the items are customisable via strings
46 used before and after the actual item.
47
48 - An itemset for "small terminals" can be provided. That is, if the
49 length of the upper line exceeds the terminal width, various
50 items get removed from the prompt to (hopefully) make it still
51 look good. Obviously this only works down to a limit.
52
53 The available items are: at, battery, change-root, date, history,
54 host, jobs, newline, path, percent, rc, rc-always, shell-level,
55 time, user, vcs, ulcorner, llcorner, urcorner, lrcorner, line, pts,
56 privileges, openparentheses, closeparentheses, openbracket,
57 closebracket, openbraces, closebraces, openanglebracket,
58 closeanglebracket, colon, pipe, space, flexline
59
60 Most of those should be self-explanatory, some may need more:
61 line - Draws a single line character
62 XYcorner - Draws a corner. The chars to replace XY are
63 X=u for upper, l for lower
64 Y=l for left, r for right
65 flexline - Same as line, but flexible length to fill remaining space
66 Only works in a two-line prompt in the upper line, that
67 is, a newline MUST appear in the setup!
68
69 Should they not fit your need, there is an easy way to have the
70 prompt include basically anything you want. Just define your own
71 items. For that you simply define them inside the
72 ':prompt:ganneff:extra:' namespace.
73
74 Example: To have the prompt include the value of the variable
75 \$FOOBAR, in red and have the variable updated by the function
76 jj_foobar, use the following:
77
78 zstyle ':prompt:ganneff:extra:foobar' pre '${PR_RED}'
79 zstyle ':prompt:ganneff:extra:foobar' post '${PR_NO_COLOR}'
80 zstyle ':prompt:ganneff:extra:foobar' token '$FOOBAR'
81 zstyle ':prompt:ganneff:extra:foobar' precmd jj_foobar
82
83 Now you can add the token \`foobar' to the list of items and voila,
84 your own stuff appears.
85
86 Note that the function part only works in zsh 4.3.5 or later (I've
87 been to lazy to replace add-zsh-hook with something for the older
88 versions).
89
90
91 The configuration of the predefined items can also be changed using
92 zsh's \`zstyle' mechanism. The context, that is used while looking
93 up styles is:
94
95 ':prompt:ganneff:<left-or-right>:<full-or-small>:<subcontext>'
96
97 Here <left-or-right> is either \`left' or \`right', signifying
98 whether the style should affect the left or the right prompt.
99
100 <full-or-small> is either \`full' or \`small' and only valid in the
101 item selection, signifying wether the item list should affect the
102 full length or the "small terminal" prompt. As "small terminal"
103 prompt does not display the right side prompt, <full-or-small> has
104 no effect on the right side prompt.
105
106 <subcontext> is either \`setup' or 'items:<item>', where \`<item>'
107 is one of the available items.
108
109 The styles/settings available under ':prompt:ganneff:':
110
111 - vcs_info (boolean): If \`true' (the default), use \`vcs_info'.
112
113 - set_vcs_info_defaults (boolean): If \`true' (the default),
114 various vcs_info settings will be done. If unset or \`false'
115 it is assumed that the user has already done this.
116
117 The default setup is:
118 zstyle ':vcs_info:*' max-exports 1
119 zstyle ':vcs_info:*' use-prompt-escapes
120 zstyle ':vcs_info:*' use_simple
121 zstyle ':vcs_info:*' stagedstr "!"
122 zstyle ':vcs_info:*' unstagedstr "?"
123 zstyle ':vcs_info:*' check-for-changes true
124 zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat \
125 "\${PR_YELLOW}%b%{\${PR_RED}%}:\${PR_YELLOW}%r\${PR_NO_COLOR}"
126 zstyle ':vcs_info:*' formats \
127 "(\${PR_YELLOW}%s\${PR_NO_COLOR})-[\${PR_GREEN}%b\${PR_NO_COLOR}]%m%u%c "
128 zstyle ':vcs_info:*' actionformats \
129 "(\${PR_YELLOW}%s\${PR_NO_COLOR})-[\${PR_GREEN}%b\${PR_NO_COLOR}-\${PR_RED}(%a)\${PR_NO_COLOR}]%m%u%c "
130
131 - colors (boolean): If \`true' (the default), use colors. b/w
132 otherwise.
133
134 - nicelines (boolean): If \`true' (the default), use special
135 magic to draw nice lines and corners. Might not work on every
136 terminal. If false, draws using plain ascii characters.
137 Linux console also seems to identify itself as if it could,
138 but then doesn't do drawing right (not in our way at least).
139
140 - battery (string): If \`none' then no battery function at all.
141 If either \`ibam' or \`acpi' then use those tools to gather
142 the current battery level.
143
144 - use-rprompt (boolean): If \`true' (the default), print the
145 right side prompt.
146
147 - items (list): The list of items used in the prompt. If \`vcs' is
148 present in the list, the theme's code invokes \`vcs_info'
149 accordingly. Default (left): rc change-root user at host path vcs
150 percent; Default (right): sad-smiley
151
152 Note that both, nicelines and colors are forced to false in case the
153 TERM variable is set to dumb.
154
155 Available styles in 'items:<item>' are: pre, post, token and precmd.
156 Pre and Post are strings that are inserted before (pre) and after
157 (post) the item in question. Token is the token itself that gets
158 inserted into PS1. Thus, the following would cause the
159 user name to be printed in red instead of the default blue:
160
161 zstyle ':prompt:ganneff:*:items:user' pre '\${PR_RED}'
162
163 and
164
165 zstyle ':prompt:ganneff:*:items:date' token '%D{%Y-%m-%d [d:%j/w:%V]}'
166
167 will output a very different date token compared with the default
168 definition of '%D{%Y-%m-%d}'.
169
170 Note, that in the above example the \`post' style may remain at its
171 default value, because its default value is '\${PR_NO_COLOR}', which
172 turns the foreground text attribute off (which is exactly, what is
173 still required with the new \`pre' value).
174
175 Possible values for the colors: \${PR_XXX} and \${PR_BOLD_XXX} with
176 XXX replaced with one of: RED GREEN YELLOW BLUE MAGENTA CYAN WHITE BLACK.
177 \${PR_NO_COLOR} resets color.
178 Using the \${PR_XXX} values instead of zsh's internal \%F{xxx} allows
179 the usage of the colors style to turn of prompt colors easily.
180
181 Last note: You really want to have "setopt promptsubst", otherwise you
182 won't like this prompt.
183 __EOF0__
184 }
185
186 prompt_ganneff_setup () {
187 emulate -L zsh
188 setopt nolocaltraps
189
190 # We forcefully overwrite colors and nicelines setting for a dumb
191 # terminal.
192 if [[ "$TERM" == "dumb" ]]; then
193 zstyle ':prompt:ganneff' colors false
194 zstyle ':prompt:ganneff' nicelines false
195 fi
196
197 # See if we can and should use extended characters to look nicer.
198 if zstyle -t ':prompt:ganneff' nicelines; then
199 typeset -A altchar
200 set -A altchar ${(s..)terminfo[acsc]}
201 # Some stuff to help us draw nice lines
202 PR_SET_CHARSET="%{$terminfo[enacs]%}"
203 PR_SHIFT_IN="%{$terminfo[smacs]%}"
204 PR_SHIFT_OUT="%{$terminfo[rmacs]%}"
205 PR_HBAR=${altchar[q]:--}
206 PR_ULCORNER=${altchar[l]:--}
207 PR_LLCORNER=${altchar[m]:--}
208 PR_LRCORNER=${altchar[j]:--}
209 PR_URCORNER=${altchar[k]:--}
210 else
211 PR_SET_CHARSET=""
212 PR_SHIFT_IN=""
213 PR_SHIFT_OUT=""
214 PR_HBAR="-"
215 PR_ULCORNER=""
216 PR_LLCORNER=""
217 PR_LRCORNER=""
218 PR_URCORNER=""
219 fi
220
221 if zstyle -t ':prompt:ganneff' colors; then
222 if [[ -n "${BLUE}" ]] && [[ -n "${YELLOW}" ]]; then
223 # Two defined, so we assume someone already defined themself
224 # the colors. We just use them and not setup our own.
225 for color in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE BLACK GREY; do
226 eval PR_$color='%{${(P)color}%}'
227 eval PR_BOLD_$color='%{$terminfo[bold]${(LP)color}%}'
228 done
229 PR_NO_COLOR="%{${reset_color}%}"
230 else
231 # Seems like colors are not defined, so set them up
232 # This duplicates docolors from 01_Terminfo.zsh, but is here to have
233 # prompt_ganneff_setup not require anything else from my dotfiles
234 if autoload -Uz colors && colors 2>/dev/null ; then
235 for COLOR in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE BLACK GREY; do
236 eval PR_$COLOR='%{$fg_no_bold[${(L)COLOR}]%}'
237 eval PR_BOLD_$COLOR='%{$fg_bold[${(L)COLOR}]%}'
238 done
239 eval PR_NO_COLOR='%{$reset_color%}'
240 else
241 PR_BLUE=$'%{\e[1;34m%}'
242 PR_RED=$'%{\e[1;31m%}'
243 PR_GREEN=$'%{\e[1;32m%}'
244 PR_CYAN=$'%{\e[1;36m%}'
245 PR_WHITE=$'%{\e[1;37m%}'
246 PR_MAGENTA=$'%{\e[1;35m%}'
247 PR_YELLOW=$'%{\e[1;33m%}'
248 PR_NO_COLOR=$'%{\e[0m%}'
249 fi
250 fi
251 else
252 PR_BLUE=''
253 PR_RED=''
254 PR_GREEN=''
255 PR_CYAN=''
256 PR_WHITE=''
257 PR_MAGENTA=''
258 PR_YELLOW=''
259 PR_NO_COLOR="%{${reset_color}%}"
260 fi
261
262 # Easy things first.
263 # The secondary prompt, printed when the shell needs more
264 # information to complete a command. %_ displays any shell constructs
265 # or quotation marks which are currently being processed.
266 if zstyle -t ':prompt:ganneff' nicelines; then
267 PS2='${PR_CYAN}${PR_SHIFT_IN}${PR_HBAR}${PR_BLUE}${PR_HBAR}${PR_SHIFT_OUT}\
268 (${PR_GREEN}%_${PR_BLUE})\
269 ${PR_SHIFT_IN}${PR_HBAR}${PR_CYAN}${PR_HBAR}${PR_SHIFT_OUT}${PR_NO_COLOR} '
270 else
271 PS2='-(%_)- '
272 fi
273 # selection prompt used within a select loop.
274 PS3='?# '
275 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
276 PS4='+%N:%i:%_> '
277
278 if zstyle -t ':prompt:ganneff' vcs_info && \
279 is439 && autoload -Uz vcs_info && vcs_info; then
280 if zstyle -t ':prompt:ganneff' set_vcs_info_defaults; then
281 # gather version control information for inclusion in a prompt
282 # we will only be using one variable, so let the code know now.
283 zstyle ':vcs_info:*' max-exports 1
284 zstyle ':vcs_info:*' use-prompt-escapes
285 zstyle ':vcs_info:*' use_simple
286 zstyle ':vcs_info:*' stagedstr "!"
287 zstyle ':vcs_info:*' unstagedstr "?"
288 zstyle ':vcs_info:*' check-for-changes true
289
290 # change vcs_info formats for the prompt
291 zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "${PR_YELLOW}%b%{${PR_RED}%}:${PR_YELLOW}%r${PR_NO_COLOR}"
292 zstyle ':vcs_info:*' formats "(${PR_YELLOW}%s${PR_NO_COLOR})-[${PR_GREEN}%b${PR_NO_COLOR}]%m%u%c "
293 zstyle ':vcs_info:*' actionformats "(${PR_YELLOW}%s${PR_NO_COLOR})-[${PR_GREEN}%b${PR_NO_COLOR}-${PR_RED}(%a)${PR_NO_COLOR}]%m%u%c "
294 fi
295 fi
296
297 # These maps define default tokens and pre-/post-decoration for items to be
298 # used within the themes. All defaults may be customised in a context sensitive
299 # matter by using zsh's `zstyle' mechanism.
300 typeset -gA ganneff_prompt_pre_default \
301 ganneff_prompt_post_default \
302 ganneff_prompt_token_default
303
304 ganneff_prompt_pre_default=(
305 at ''
306 battery ' '
307 change-root ''
308 date '${PR_BLUE}'
309 history '${PR_GREEN}'
310 host '${PR_RED}'
311 jobs '${PR_CYAN}'
312 newline ''
313 path '${PR_MAGENTA}'
314 percent ''
315 rc '${PR_RED}'
316 rc-always ''
317 shell-level '${PR_RED}'
318 time '${PR_BLUE}'
319 user '${PR_BLUE}'
320 vcs ''
321 ulcorner '${PR_SHIFT_IN}'
322 llcorner '${PR_SHIFT_IN}'
323 urcorner '${PR_SHIFT_IN}'
324 lrcorner '${PR_SHIFT_IN}'
325 line '${PR_SHIFT_IN}'
326 pts ''
327 privileges ''
328 openparentheses ''
329 closeparentheses ''
330 openbracket ''
331 closebracket ''
332 openbraces ''
333 closebraces ''
334 openanglebracket ''
335 closeanglebracket ''
336 pipe ''
337 space ''
338 colon ''
339 flexline '${PR_SHIFT_IN}'
340 )
341
342
343 ganneff_prompt_post_default=(
344 at ''
345 battery ''
346 change-root ''
347 date '${PR_NO_COLOR}'
348 history '${PR_NO_COLOR}'
349 host '${PR_NO_COLOR}'
350 jobs '${PR_NO_COLOR}'
351 newline ''
352 path '${PR_NO_COLOR}'
353 percent ''
354 rc '${PR_NO_COLOR}'
355 rc-always ''
356 shell-level '${PR_NO_COLOR}'
357 time '${PR_NO_COLOR}'
358 user '${PR_NO_COLOR}'
359 vcs ''
360 ulcorner '${PR_SHIFT_OUT}'
361 llcorner '${PR_SHIFT_OUT}'
362 urcorner '${PR_SHIFT_OUT}'
363 lrcorner '${PR_SHIFT_OUT}'
364 line '${PR_SHIFT_OUT}'
365 pts ''
366 privileges ''
367 openparentheses ''
368 closeparentheses ''
369 openbracket ''
370 closebracket ''
371 openbraces ''
372 closebraces ''
373 openanglebracket ''
374 closeanglebracket ''
375 pipe ''
376 space ''
377 colon ''
378 flexline '${PR_SHIFT_OUT}'
379 )
380
381 ganneff_prompt_token_default=(
382 at '@'
383 battery 'PERCENT'
384 change-root 'debian_chroot'
385 date '%D{%Y-%m-%d}'
386 history '{#%!}'
387 host '%m'
388 jobs '[%j running job(s)] '
389 newline $'\n'
390 path '%40<..<%~%<<'
391 percent '% # '
392 rc '%(?..%? )'
393 rc-always '%?'
394 shell-level '%(2L.%L.)'
395 time '%D{%H:%M:%S}'
396 user '%n'
397 vcs '0'
398 ulcorner '${PR_ULCORNER}'
399 llcorner '${PR_LLCORNER}'
400 urcorner '${PR_URCORNER}'
401 lrcorner '${PR_LRCORNER}'
402 line '${PR_HBAR}'
403 pts '%y'
404 privileges '%#'
405 openparentheses '('
406 closeparentheses ')'
407 openbracket '['
408 closebracket ']'
409 openbraces '{'
410 closebraces '}'
411 openanglebracket '<'
412 closeanglebracket '>'
413 pipe '|'
414 space ' '
415 colon ':'
416 flexline 'PR_FLEXLINE'
417 )
418
419 PR_FLEXLINE=""
420 add-zsh-hook precmd prompt_ganneff_precmd
421 # Call the winch function once to ensure the length gets calculated
422 # correctly
423 prompt_ganneff_winch
424 local pr_battery
425 zstyle -s ':prompt:ganneff' battery pr_battery
426 if [[ $pr_battery != "none" ]]; then
427 add-zsh-hook precmd prompt_ganneff_battery
428 prompt_ganneff_battery
429 fi
430
431 functions[TRAPWINCH]="${functions[TRAPWINCH]//prompt_ganneff_winch}
432 prompt_ganneff_winch"
433 }
434
435 prompt_ganneff_precmd () {
436 emulate -L zsh
437 setopt nolocaltraps
438
439 zstyle -t ':prompt:ganneff' vcs_info && vcs_info
440 local -a left_items right_items
441 left_items=(ulcorner line openbracket user at host colon pts closebracket line history flexline
442 openbracket path closebracket line urcorner newline
443 llcorner line rc openbracket time closebracket line vcs line change-root pipe space)
444 PR_PS1=""; nomore=0
445 ganneff_prompt_addto PS1 full "${left_items[@]}"
446 if zstyle -T ":prompt:ganneff:right:setup" use-rprompt; then
447 right_items=(space pipe line openbracket date closebracket line lrcorner)
448 ganneff_prompt_addto RPS1 full "${right_items[@]}"
449 fi
450
451 # Now a kind-of-hack to reduce the prompt when we run out of space.
452 promptsize=${#PR_PS1}
453 if [[ ${promptsize} -lt ${TERMWIDTH} ]]; then
454 # the q here should be ${PR_HBAR}, but for some reason zsh didn't like me,
455 # so meh
456 if zstyle -t ':prompt:ganneff' nicelines && [[ "$TERM" != dumb ]] \
457 && [[ "$TERM" != "linux" ]]; then
458 PR_FLEXLINE="${(l.(($TERMWIDTH - $promptsize ))..q.)}"
459 else
460 PR_FLEXLINE="${(l.(($TERMWIDTH - $promptsize ))..-.)}"
461 fi
462 else
463 # Small size prompt is needed
464 left_items=(ulcorner line openbracket user at host closebracket line openbracket path closebracket newline
465 llcorner line rc openbracket time closebracket line vcs line pipe space)
466 ganneff_prompt_addto PS1 small "${left_items[@]}"
467 # And with a small prompt, we don't show the right size at all.
468 RPS1=""
469 fi
470 }
471
472 prompt_ganneff_length () {
473 (( TERMWIDTH = ${COLUMNS} - 1 ))
474 }
475
476 prompt_ganneff_winch () {
477 emulate -L zsh
478 setopt nolocaltraps noksharrays unset
479
480 # Delete ourself from TRAPWINCH if not using our precmd insert.
481 [[ $precmd_functions = *prompt_ganneff_precmd* ]] && prompt_ganneff_length ||
482 functions[TRAPWINCH]="${functions[TRAPWINCH]//prompt_ganneff_winch}"
483 }
484
485 ganneff_typeset_and_wrap () {
486 emulate -L zsh
487 local target="$1"
488 local new="$2"
489 local left="$3"
490 local right="$4"
491
492 if (( ${+parameters[$new]} )); then
493 typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
494 fi
495 }
496
497 ganneff_prompt_addto () {
498 emulate -L zsh
499 local target="$1"
500 local size="$2"
501 local lr it apre apost new v prefunc
502 local -a items
503 shift
504 shift
505
506 [[ $target == PS1 ]] && lr=left || lr=right
507 zstyle -a ":prompt:ganneff:${lr}:${size}:setup" items items || items=( "$@" )
508 typeset -g "${target}="
509 for it in "${items[@]}"; do
510 zstyle -s ":prompt:ganneff:${lr}:items:$it" pre apre \
511 || zstyle -s ":prompt:ganneff:extra:$it" pre apre \
512 || apre=${ganneff_prompt_pre_default[$it]}
513 zstyle -s ":prompt:ganneff:${lr}:items:$it" post apost \
514 || zstyle -s ":prompt:ganneff:extra:$it" post apost \
515 || apost=${ganneff_prompt_post_default[$it]}
516 zstyle -s ":prompt:ganneff:${lr}:items:$it" token new \
517 || zstyle -s ":prompt:ganneff:extra:$it" token new \
518 || new=${ganneff_prompt_token_default[$it]}
519
520 # Now check if there is the wish for a precmd function and if so,
521 # run it
522 zstyle -s ":prompt:ganneff:extra:$it" precmd prefunc
523 if [[ -n "${prefunc}" ]]; then
524 ${prefunc} || true
525 fi
526
527 typeset -g "${target}=${(P)target}${apre}"
528 # Store the expanded value in PR_PS1, as we use that for length calculations
529 [[ $it == "newline" ]] && nomore=1
530 if [[ $nomore -eq 0 ]] && [[ $it != "flexline" ]] && PR_PS1+=${(e%)new}
531 case $it in
532 battery)
533 ganneff_typeset_and_wrap $target $new '' ''
534 ;;
535 change-root)
536 ganneff_typeset_and_wrap $target $new '(' ')'
537 ;;
538 flexline)
539 typeset -g "${target}=${(P)target}\${${new}}"
540 ;;
541 ganneff-chroot)
542 if [[ -n ${(P)new} ]]; then
543 typeset -g "${target}=${(P)target}(CHROOT)"
544 fi
545 ;;
546 vcs)
547 v="vcs_info_msg_${new}_"
548 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
549 typeset -g "${target}=${(P)target}${(P)v}"
550 fi
551 ;;
552 *) typeset -g "${target}=${(P)target}${new}" ;;
553 esac
554 typeset -g "${target}=${(P)target}${apost}"
555 done
556 }
557
558 prompt_ganneff_battery() {
559 zstyle -s ':prompt:ganneff' battery pr_battery
560 case $pr_battery in
561 ibam)
562 local ACPIDATA=$(ibam --percentbattery 2>/dev/null || echo "")
563 PERCENT=${${ACPIDATA[(f)1]}[(w)-2]}
564 ;;
565 acpi)
566 PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
567 ;;
568 *)
569 PERCENT=""
570 ;;
571 esac
572
573 if [[ -z "$PERCENT" ]] ; then
574 PERCENT="No battery or $pr_battery not present "
575 else
576 if [[ "$PERCENT" -lt 20 ]] ; then
577 PERCENT="warning: ${PERCENT}%%"
578 else
579 PERCENT="${PERCENT}%%"
580 fi
581 fi
582 }
583
584 is439(){
585 [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
586 || $ZSH_VERSION == <5->* ]] && return 0
587 return 1
588 }
589
590 prompt_ganneff_setup "$@"