.
[zsh.git] / .zsh / functions / prompt_ganneff_setup
1 # -*- mode:sh -*-
2
3 # This prompt is based on work of other people.
4 #
5 # The prompt itself is based on various others:
6 # - The "design" is taken from Phil!'s ZSH prompt, as found on
7 # http://aperiodic.net/phil/prompt/
8 #
9 # - The tech using zstyle is inspired by the prompt as used by
10 # the grml-live system <http://grml.org>, see
11 # http://git.grml.org/?p=grml-etc-core.git;a=summary for details
12 # on theirs.
13 # A good number of their support functions are also taken, though
14 # they got renamed from grml_* to ganneff_* to have a single namespace
15 # here.
16 #
17 # - The winch function as seen in the prompt theme "bart", delivered
18 # with zsh
19
20 prompt_ganneff_help () {
21 cat <<__EOF0__
22 prompt ganneff
23
24 This is the prompt as used by (who would have guessed) Ganneff. By
25 default it is a two-line prompt. You can find its latest version at
26 http://git.ganneff.de/cgi-bin/gitweb.cgi?p=zsh.git;a=summary
27
28 The prompt itself is based on various others:
29 - The "design" is taken from Phil!'s ZSH prompt, as found on
30 http://aperiodic.net/phil/prompt/
31
32 - The technic using zstyle is inspired by the prompt as used by
33 the grml-live system <http://grml.org>, see
34 http://git.grml.org/?p=grml-etc-core.git;a=summary for details
35 on theirs.
36
37 The prompt integrates with zsh's prompt themes system and uses the
38 zstyle system for its configuration. It is configurable as much as
39 seems to make sense. In particular, these aspects are customisable:
40
41 - The items used in the prompt and their order (e.g. you can
42 remove \`user' from the list of activated items, which will
43 cause the user name to be omitted from the prompt string).
44
45 - The attributes used with the items are customisable via strings
46 used before and after the actual item.
47
48 - An itemset for "small terminals" can be provided. That is, if the
49 length of the upper line exceeds the terminal width, various
50 items get removed from the prompt to (hopefully) make it still
51 look good. Obviously this only works down to a limit.
52
53 The available items are: at, battery, change-root, date, history,
54 host, jobs, newline, path, percent, rc, rc-always, shell-level,
55 time, user, vcs, ulcorner, llcorner, urcorner, lrcorner, line, pts,
56 openbracket, closebracket, pipe, space, flexline
57
58 Most of those should be self-explanatory, some may need more:
59 line - Draws a single line character
60 XYcorner - Draws a corner. The chars to replace XY are
61 X=u for upper, l for lower
62 Y=l for left, r for right
63 flexline - Same as line, but flexible length to fill remaining space
64 Only works in a two-line prompt in the upper line, that
65 is, a newline MUST appear in the setup!
66
67 Should they not fit your need, there is an easy way to have the
68 prompt include basically anything you want. Just define your own
69 items. For that you simply define them inside the
70 ':prompt:ganneff:extra:' namespace.
71
72 Example: To have the prompt include the value of the variable
73 \$FOOBAR, in red and have the variable updated by the function
74 jj_foobar, use the following:
75
76 zstyle ':prompt:ganneff:extra:foobar' pre '${PR_RED}'
77 zstyle ':prompt:ganneff:extra:foobar' post '${PR_NO_COLOR}'
78 zstyle ':prompt:ganneff:extra:foobar' token '$FOOBAR'
79 zstyle ':prompt:ganneff:extra:foobar' precmd jj_foobar
80
81 Now you can add the token \`foobar' to the list of items and voila,
82 your own stuff appears.
83
84 Note that the function part only works in zsh 4.3.5 or later (I've
85 been to lazy to replace add-zsh-hook with something for the older
86 versions).
87
88
89 The configuration of the predefined items can also be changed using
90 zsh's \`zstyle' mechanism. The context, that is used while looking
91 up styles is:
92
93 ':prompt:ganneff:<left-or-right>:<full-or-small>:<subcontext>'
94
95 Here <left-or-right> is either \`left' or \`right', signifying
96 whether the style should affect the left or the right prompt.
97
98 <full-or-small> is either \`full' or \`small' and only valid in the
99 item selection, signifying wether the item list should affect the
100 full length or the "small terminal" prompt. As "small terminal"
101 prompt does not display the right side prompt, <full-or-small> has
102 no effect on the right side prompt.
103
104 <subcontext> is either \`setup' or 'items:<item>', where \`<item>'
105 is one of the available items.
106
107 The styles/settings available under ':prompt:ganneff:':
108
109 - vcs_info (boolean): If \`true' (the default), use \`vcs_info'.
110
111 - set_vcs_info_defaults (boolean): If \`true' (the default),
112 various vcs_info settings will be done. If unset or \`false'
113 it is assumed that the user has already done this.
114
115 The default setup is:
116 zstyle ':vcs_info:*' max-exports 1
117 zstyle ':vcs_info:*' use-prompt-escapes
118 zstyle ':vcs_info:*' use_simple
119 zstyle ':vcs_info:*' stagedstr "!"
120 zstyle ':vcs_info:*' unstagedstr "?"
121 zstyle ':vcs_info:*' check-for-changes true
122 zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat \
123 "\${PR_YELLOW}%b%{\${PR_RED}%}:\${PR_YELLOW}%r\${PR_NO_COLOR}"
124 zstyle ':vcs_info:*' formats \
125 "(\${PR_YELLOW}%s\${PR_NO_COLOR})-[\${PR_GREEN}%b\${PR_NO_COLOR}]%m%u%c "
126 zstyle ':vcs_info:*' actionformats \
127 "(\${PR_YELLOW}%s\${PR_NO_COLOR})-[\${PR_GREEN}%b\${PR_NO_COLOR}-\${PR_RED}(%a)\${PR_NO_COLOR}]%m%u%c "
128
129 - colors (boolean): If \`true' (the default), use colors. b/w
130 otherwise.
131
132 - nicelines (boolean): If \`true' (the default), use special
133 magic to draw nice lines and corners. Might not work on every
134 terminal. If false, draws using plain ascii characters.
135 Linux console also seems to identify itself as if it could,
136 but then doesn't do drawing right (not in our way at least).
137
138 - battery (string): If \`none' then no battery function at all.
139 If either \`ibam' or \`acpi' then use those tools to gather
140 the current battery level.
141
142 - use-rprompt (boolean): If \`true' (the default), print the
143 right side prompt.
144
145 - items (list): The list of items used in the prompt. If \`vcs' is
146 present in the list, the theme's code invokes \`vcs_info'
147 accordingly. Default (left): rc change-root user at host path vcs
148 percent; Default (right): sad-smiley
149
150 Note that both, nicelines and colors are forced to false in case the
151 TERM variable is set to dumb.
152
153 Available styles in 'items:<item>' are: pre, post, token and precmd.
154 Pre and Post are strings that are inserted before (pre) and after
155 (post) the item in question. Token is the token itself that gets
156 inserted into PS1. Thus, the following would cause the
157 user name to be printed in red instead of the default blue:
158
159 zstyle ':prompt:ganneff:*:items:user' pre '\${PR_RED}'
160
161 and
162
163 zstyle ':prompt:ganneff:*:items:date' token '%D{%Y-%m-%d [d:%j/w:%V]}'
164
165 will output a very different date token compared with the default
166 definition of '%D{%Y-%m-%d}'.
167
168 Note, that in the above example the \`post' style may remain at its
169 default value, because its default value is '\${PR_NO_COLOR}', which
170 turns the foreground text attribute off (which is exactly, what is
171 still required with the new \`pre' value).
172
173 Possible values for the colors: \${PR_XXX} and \${PR_BOLD_XXX} with
174 XXX replaced with one of: RED GREEN YELLOW BLUE MAGENTA CYAN WHITE BLACK.
175 \${PR_NO_COLOR} resets color.
176 Using the \${PR_XXX} values instead of zsh's internal \%F{xxx} allows
177 the usage of the colors style to turn of prompt colors easily.
178
179 Last note: You really want to have "setopt promptsubst", otherwise you
180 won't like this prompt.
181 __EOF0__
182 }
183
184 prompt_ganneff_setup () {
185 emulate -L zsh
186 setopt nolocaltraps
187
188 # We forcefully overwrite colors and nicelines setting for a dumb
189 # terminal.
190 if [[ "$TERM" == "dumb" ]]; then
191 zstyle ':prompt:ganneff' colors false
192 zstyle ':prompt:ganneff' nicelines false
193 fi
194
195 # See if we can and should use extended characters to look nicer.
196 if zstyle -t ':prompt:ganneff' nicelines; then
197 typeset -A altchar
198 set -A altchar ${(s..)terminfo[acsc]}
199 # Some stuff to help us draw nice lines
200 PR_SET_CHARSET="%{$terminfo[enacs]%}"
201 PR_SHIFT_IN="%{$terminfo[smacs]%}"
202 PR_SHIFT_OUT="%{$terminfo[rmacs]%}"
203 PR_HBAR=${altchar[q]:--}
204 PR_ULCORNER=${altchar[l]:--}
205 PR_LLCORNER=${altchar[m]:--}
206 PR_LRCORNER=${altchar[j]:--}
207 PR_URCORNER=${altchar[k]:--}
208 else
209 PR_SET_CHARSET=""
210 PR_SHIFT_IN=""
211 PR_SHIFT_OUT=""
212 PR_HBAR="-"
213 PR_ULCORNER=""
214 PR_LLCORNER=""
215 PR_LRCORNER=""
216 PR_URCORNER=""
217 fi
218
219 if zstyle -t ':prompt:ganneff' colors; then
220 if [[ -n "${BLUE}" ]] && [[ -n "${YELLOW}" ]]; then
221 # Two defined, so we assume someone already defined themself
222 # the colors. We just use them and not setup our own.
223 for color in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE; do
224 eval PR_$color='%{${(P)color}%}'
225 eval PR_BOLD_$color='%{$terminfo[bold]${(LP)color}%}'
226 done
227 PR_NO_COLOR="%{${reset_color}%}"
228 else
229 # Seems like colors are not defined, so set them up
230 # This duplicates docolors from 01_Terminfo.zsh, but is here to have
231 # prompt_ganneff_setup not require anything else from my dotfiles
232 if autoload -Uz colors && colors 2>/dev/null ; then
233 for COLOR in RED GREEN YELLOW BLUE MAGENTA CYAN BLACK WHITE; do
234 eval PR_$COLOR='%{$fg_no_bold[${(L)COLOR}]%}'
235 eval PR_BOLD_$COLOR='%{$fg_bold[${(L)COLOR}]%}'
236 done
237 eval PR_NO_COLOR='%{$reset_color%}'
238 else
239 PR_BLUE=$'%{\e[1;34m%}'
240 PR_RED=$'%{\e[1;31m%}'
241 PR_GREEN=$'%{\e[1;32m%}'
242 PR_CYAN=$'%{\e[1;36m%}'
243 PR_WHITE=$'%{\e[1;37m%}'
244 PR_MAGENTA=$'%{\e[1;35m%}'
245 PR_YELLOW=$'%{\e[1;33m%}'
246 PR_NO_COLOR=$'%{\e[0m%}'
247 fi
248 fi
249 else
250 PR_BLUE=''
251 PR_RED=''
252 PR_GREEN=''
253 PR_CYAN=''
254 PR_WHITE=''
255 PR_MAGENTA=''
256 PR_YELLOW=''
257 PR_NO_COLOR="%{${reset_color}%}"
258 fi
259
260 # Easy things first.
261 # The secondary prompt, printed when the shell needs more
262 # information to complete a command. %_ displays any shell constructs
263 # or quotation marks which are currently being processed.
264 if zstyle -t ':prompt:ganneff' nicelines; then
265 PS2='${PR_CYAN}${PR_SHIFT_IN}${PR_HBAR}${PR_BLUE}${PR_HBAR}${PR_SHIFT_OUT}\
266 (${PR_GREEN}%_${PR_BLUE})\
267 ${PR_SHIFT_IN}${PR_HBAR}${PR_CYAN}${PR_HBAR}${PR_SHIFT_OUT}${PR_NO_COLOR} '
268 else
269 PS2='-(%_)- '
270 fi
271 # selection prompt used within a select loop.
272 PS3='?# '
273 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
274 PS4='+%N:%i:%_> '
275
276 if zstyle -t ':prompt:ganneff' vcs_info && \
277 is439 && autoload -Uz vcs_info && vcs_info; then
278 if zstyle -t ':prompt:ganneff' set_vcs_info_defaults; then
279 # gather version control information for inclusion in a prompt
280 # we will only be using one variable, so let the code know now.
281 zstyle ':vcs_info:*' max-exports 1
282 zstyle ':vcs_info:*' use-prompt-escapes
283 zstyle ':vcs_info:*' use_simple
284 zstyle ':vcs_info:*' stagedstr "!"
285 zstyle ':vcs_info:*' unstagedstr "?"
286 zstyle ':vcs_info:*' check-for-changes true
287
288 # change vcs_info formats for the prompt
289 zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "${PR_YELLOW}%b%{${PR_RED}%}:${PR_YELLOW}%r${PR_NO_COLOR}"
290 zstyle ':vcs_info:*' formats "(${PR_YELLOW}%s${PR_NO_COLOR})-[${PR_GREEN}%b${PR_NO_COLOR}]%m%u%c "
291 zstyle ':vcs_info:*' actionformats "(${PR_YELLOW}%s${PR_NO_COLOR})-[${PR_GREEN}%b${PR_NO_COLOR}-${PR_RED}(%a)${PR_NO_COLOR}]%m%u%c "
292 fi
293 fi
294
295 # These maps define default tokens and pre-/post-decoration for items to be
296 # used within the themes. All defaults may be customised in a context sensitive
297 # matter by using zsh's `zstyle' mechanism.
298 typeset -gA ganneff_prompt_pre_default \
299 ganneff_prompt_post_default \
300 ganneff_prompt_token_default
301
302 ganneff_prompt_pre_default=(
303 at ''
304 battery ' '
305 change-root ''
306 date '${PR_BLUE}'
307 history '${PR_GREEN}'
308 host '${PR_RED}'
309 jobs '${PR_CYAN}'
310 newline ''
311 path '${PR_MAGENTA}'
312 percent ''
313 rc '${PR_RED}'
314 rc-always ''
315 shell-level '${PR_RED}'
316 time '${PR_BLUE}'
317 user '${PR_BLUE}'
318 vcs ''
319 ulcorner '${PR_SHIFT_IN}'
320 llcorner '${PR_SHIFT_IN}'
321 urcorner '${PR_SHIFT_IN}'
322 lrcorner '${PR_SHIFT_IN}'
323 line '${PR_SHIFT_IN}'
324 pts ''
325 openbracket ''
326 closebracket ''
327 pipe ''
328 space ''
329 flexline '${PR_SHIFT_IN}'
330 )
331
332 ganneff_prompt_post_default=(
333 at ''
334 battery ''
335 change-root ''
336 date '${PR_NO_COLOR}'
337 history '${PR_NO_COLOR}'
338 host '${PR_NO_COLOR}'
339 jobs '${PR_NO_COLOR}'
340 newline ''
341 path '${PR_NO_COLOR}'
342 percent ''
343 rc '${PR_NO_COLOR}'
344 rc-always ''
345 shell-level '${PR_NO_COLOR}'
346 time '${PR_NO_COLOR}'
347 user '${PR_NO_COLOR}'
348 vcs ''
349 ulcorner '${PR_SHIFT_OUT}'
350 llcorner '${PR_SHIFT_OUT}'
351 urcorner '${PR_SHIFT_OUT}'
352 lrcorner '${PR_SHIFT_OUT}'
353 line '${PR_SHIFT_OUT}'
354 pts ''
355 openbracket ''
356 closebracket ''
357 pipe ''
358 space ''
359 flexline '${PR_SHIFT_OUT}'
360 )
361
362 ganneff_prompt_token_default=(
363 at '@'
364 battery 'PERCENT'
365 change-root 'debian_chroot'
366 date '%D{%Y-%m-%d}'
367 history '{#%!}'
368 host '%m'
369 jobs '[%j running job(s)] '
370 newline $'\n'
371 path '%40<..<%~%<<'
372 percent '% # '
373 rc '%(?..%? )'
374 rc-always '%?'
375 shell-level '%(2L.%L.)'
376 time '%D{%H:%M:%S}'
377 user '%n'
378 vcs '0'
379 ulcorner '${PR_ULCORNER}'
380 llcorner '${PR_LLCORNER}'
381 urcorner '${PR_URCORNER}'
382 lrcorner '${PR_LRCORNER}'
383 line '${PR_HBAR}'
384 pts ':%y'
385 openbracket '('
386 closebracket ')'
387 pipe '|'
388 space ' '
389 flexline 'PR_FLEXLINE'
390 )
391
392 PR_FLEXLINE=""
393 add-zsh-hook precmd prompt_ganneff_precmd
394 # Call the winch function once to ensure the length gets calculated
395 # correctly
396 prompt_ganneff_winch
397 local pr_battery
398 zstyle -s ':prompt:ganneff' battery pr_battery
399 if [[ $pr_battery != "none" ]]; then
400 add-zsh-hook precmd prompt_ganneff_battery
401 prompt_ganneff_battery
402 fi
403
404 functions[TRAPWINCH]="${functions[TRAPWINCH]//prompt_ganneff_winch}
405 prompt_ganneff_winch"
406 }
407
408 prompt_ganneff_precmd () {
409 emulate -L zsh
410 setopt nolocaltraps
411
412 zstyle -t ':prompt:ganneff' vcs_info && vcs_info
413 local -a left_items right_items
414 left_items=(ulcorner line openbracket user at host pts closebracket line history flexline
415 openbracket path closebracket line urcorner newline
416 llcorner line rc openbracket time closebracket line vcs line change-root pipe space)
417 PR_PS1=""; nomore=0
418 ganneff_prompt_addto PS1 full "${left_items[@]}"
419 if zstyle -T ":prompt:ganneff:right:setup" use-rprompt; then
420 right_items=(space pipe line openbracket date closebracket line lrcorner)
421 ganneff_prompt_addto RPS1 full "${right_items[@]}"
422 fi
423
424 # Now a kind-of-hack to reduce the prompt when we run out of space.
425 promptsize=${#PR_PS1}
426 if [[ ${promptsize} -lt ${TERMWIDTH} ]]; then
427 # the q here should be ${PR_HBAR}, but for some reason zsh didn't like me,
428 # so meh
429 if zstyle -t ':prompt:ganneff' nicelines && [[ "$TERM" != dumb ]] \
430 && [[ "$TERM" != "linux" ]]; then
431 PR_FLEXLINE="${(l.(($TERMWIDTH - $promptsize ))..q.)}"
432 else
433 PR_FLEXLINE="${(l.(($TERMWIDTH - $promptsize ))..-.)}"
434 fi
435 else
436 # Small size prompt is needed
437 left_items=(ulcorner line openbracket user at host closebracket line openbracket path closebracket newline
438 llcorner line rc openbracket time closebracket line vcs line pipe space)
439 ganneff_prompt_addto PS1 small "${left_items[@]}"
440 # And with a small prompt, we don't show the right size at all.
441 RPS1=""
442 fi
443 }
444
445 prompt_ganneff_length () {
446 (( TERMWIDTH = ${COLUMNS} - 1 ))
447 }
448
449 prompt_ganneff_winch () {
450 emulate -L zsh
451 setopt nolocaltraps noksharrays unset
452
453 # Delete ourself from TRAPWINCH if not using our precmd insert.
454 [[ $precmd_functions = *prompt_ganneff_precmd* ]] && prompt_ganneff_length ||
455 functions[TRAPWINCH]="${functions[TRAPWINCH]//prompt_ganneff_winch}"
456 }
457
458 ganneff_typeset_and_wrap () {
459 emulate -L zsh
460 local target="$1"
461 local new="$2"
462 local left="$3"
463 local right="$4"
464
465 if (( ${+parameters[$new]} )); then
466 typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
467 fi
468 }
469
470 ganneff_prompt_addto () {
471 emulate -L zsh
472 local target="$1"
473 local size="$2"
474 local lr it apre apost new v prefunc
475 local -a items
476 shift
477 shift
478
479 [[ $target == PS1 ]] && lr=left || lr=right
480 zstyle -a ":prompt:ganneff:${lr}:${size}:setup" items items || items=( "$@" )
481 typeset -g "${target}="
482 for it in "${items[@]}"; do
483 zstyle -s ":prompt:ganneff:${lr}:items:$it" pre apre \
484 || zstyle -s ":prompt:ganneff:extra:$it" pre apre \
485 || apre=${ganneff_prompt_pre_default[$it]}
486 zstyle -s ":prompt:ganneff:${lr}:items:$it" post apost \
487 || zstyle -s ":prompt:ganneff:extra:$it" post apost \
488 || apost=${ganneff_prompt_post_default[$it]}
489 zstyle -s ":prompt:ganneff:${lr}:items:$it" token new \
490 || zstyle -s ":prompt:ganneff:extra:$it" token new \
491 || new=${ganneff_prompt_token_default[$it]}
492
493 # Now check if there is the wish for a precmd function and if so,
494 # run it
495 zstyle -s ":prompt:ganneff:extra:$it" precmd prefunc
496 if [[ -n "${prefunc}" ]]; then
497 ${prefunc} || true
498 fi
499
500 typeset -g "${target}=${(P)target}${apre}"
501 # Store the expanded value in PR_PS1, as we use that for length calculations
502 [[ $it == "newline" ]] && nomore=1
503 if [[ $nomore -eq 0 ]] && [[ $it != "flexline" ]] && PR_PS1+=${(e%)new}
504 case $it in
505 battery)
506 ganneff_typeset_and_wrap $target $new '' ''
507 ;;
508 change-root)
509 ganneff_typeset_and_wrap $target $new '(' ')'
510 ;;
511 flexline)
512 typeset -g "${target}=${(P)target}\${${new}}"
513 ;;
514 ganneff-chroot)
515 if [[ -n ${(P)new} ]]; then
516 typeset -g "${target}=${(P)target}(CHROOT)"
517 fi
518 ;;
519 vcs)
520 v="vcs_info_msg_${new}_"
521 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
522 typeset -g "${target}=${(P)target}${(P)v}"
523 fi
524 ;;
525 *) typeset -g "${target}=${(P)target}${new}" ;;
526 esac
527 typeset -g "${target}=${(P)target}${apost}"
528 done
529 }
530
531 prompt_ganneff_battery() {
532 zstyle -s ':prompt:ganneff' battery pr_battery
533 case $pr_battery in
534 ibam)
535 local ACPIDATA=$(ibam --percentbattery 2>/dev/null || echo "")
536 PERCENT=${${ACPIDATA[(f)1]}[(w)-2]}
537 ;;
538 acpi)
539 PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
540 ;;
541 *)
542 PERCENT=""
543 ;;
544 esac
545
546 if [[ -z "$PERCENT" ]] ; then
547 PERCENT="No battery or $pr_battery not present "
548 else
549 if [[ "$PERCENT" -lt 20 ]] ; then
550 PERCENT="warning: ${PERCENT}%%"
551 else
552 PERCENT="${PERCENT}%%"
553 fi
554 fi
555 }
556
557 prompt_ganneff_setup "$@"